开放问题

这些都是已知的开放问题。

• rustkey::random 表示一个应（某种程度上）具有密码学安全的随机字节生成器。这尚未得到验证。
  它使用固件中的 blake2s 来生成随机数，使用持久性缓冲区来维护使用之间的某些状态，并使用来自 TRNG 的字节将新的熵引入混合。使用 seed 参数可以手动注入额外的熵。
• cargo build 警告不稳定功能。也许我们应该为此创建一个问题。

  cargo build --release --bins
  warning: unknown and unstable feature specified for `-Ctarget-feature`: `zmmul`
    |
    = note: it is still passed through to the codegen backend, but use of this feature might be unsound and the behavior of this feature can change in the future
    = help: consider filing a feature request
  

除了这里列出的项目外，我还为需要考虑的事情留下了 TODO 注释，即使它们最终被证明是不相关的。

决策

• 不使用堆/动态内存分配（目前）。
  • 使用crate 'heapless'在栈上实现某些数据结构。
• 不线程安全（直到使用std或自定义线程时才需要）。
• 在启动执行方面不使用依赖项（例如rust-embedded/riscv）
  1. 增加了一层不透明性，非直接的逻辑。
  2. 更全面的初始化，解决了不支持的功能，执行了不必要的初始化。
  3. 相反，在全局汇编中初始化时，从入口点（链接脚本）到初始化再到main的执行是明显的。
• 不正确使用函数可能会导致panic。
• 实现（在罕见情况下）可能会更改。
  例如，如果random在合理约束下可以改进。

入门

以下描述了构建加载到TKey的应用程序二进制文件所需的应用程序设置。

以下步骤是必须的

• 为riscv32i-unknown-none-elf配置构建，并添加额外的CPU功能 'c'（压缩指令）和'Zmmul'（仅乘法指令，即不除法）。其他构建选项有助于生成更小的二进制文件，以便它可以装入128 KiB的内存。
• 应用合适的链接脚本。
• 创建一个入口点，用于执行应用程序的TKey设备的基本初始化。
• 使用llvm-objcopy为tillitis TKey创建原始裸机应用程序二进制文件。
• 应用程序：src/main.rs是一个使用此设置并演示工作TKey-app的示例。

配置构建

构建目标riscv32i-unknown-none-elf必须在rust生态系统中可用。

rustup target add riscv32i-unknown-none-elf

以下构建配置启用了必要的功能和选项。

.cargo/config.toml:

[build]
target = "riscv32i-unknown-none-elf"

[profile.dev]
panic = "abort"

[profile.release]
codegen-units = 1 # No parallelism, may increase ability to optimize.
debug = false # Do not produce a debug-build.
debug-assertions = false # Drop debug-assertions.
opt-level = 3 # Perform a high level of optimization, also 'z' to specifically target size.
overflow-checks = false
strip = true # Currently translates to 'strip = "symbols"', i.e. strip all excess information.
lto = true # Perform link-time optimization, to further optimize and reduce binary size.
panic = "abort"

[target.riscv32i-unknown-none-elf]
rustflags = [
	"-Ctarget-feature=+c,+zmmul",
	"-Ccode-model=medium",
	"-Cpanic=abort",
	"-Crelocation-model=pic",
	"-Clink-arg=-Tapp.lds",
]

此配置适用于--release构建。

注意：panic设置应该消除在链接脚本中需要.eh_frame部分的需求，但当前并非如此。

链接脚本

以下链接脚本定义了TKey的内存区域。

对原始链接脚本的变化

• 定义_stack_start符号，以便可以在汇编代码之外修改此地址。
• _stack_start被分配了不同的值：'ORIGIN(RAM)+LENGTH(RAM)'从原始值'0x4001fff0。原始值略低，我怀疑这是不必要的，因为在使用之前已经操纵了堆栈指针。（问题）
• 向.text区域添加了*(.eh_frame)。
  这不应该有必要，因为 panic=abort 应该会消除对 .eh_frame 节的需要，根据许多参考资料和我的理解，因为它禁用了堆栈展开。不应该需要保留额外数据。然而，这种改变却非常突然，没有明确的解释。添加 .eh_frame 节会产生一个适应这种情况的内存布局，尽管如果我们能完全去掉它会更好。

/*
 * Copyright (C) 2022, 2023 - Tillitis AB
 * SPDX-License-Identifier: GPL-2.0-only
 */

OUTPUT_ARCH( "riscv" )
ENTRY(_start)

MEMORY
{
	RAM (rwx)   : ORIGIN = 0x40000000, LENGTH = 0x20000 /* 128 KB */
}

SECTIONS
{
	.text.init :
	{
		*(.text.init)
	} >RAM

	.text :
	{
		. = ALIGN(4);
		*(.text)           /* .text sections (code) */
		*(.text*)          /* .text* sections (code) */
		*(.rodata)         /* .rodata sections (constants, strings, etc.) */
		*(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
		*(.srodata)        /* .rodata sections (constants, strings, etc.) */
		*(.srodata*)       /* .rodata* sections (constants, strings, etc.) */
		*(.eh_frame)
		. = ALIGN(4);
		_etext = .;
		_sidata = _etext;
	} >RAM

	.data : AT (_etext)
	{
		. = ALIGN(4);
		_sdata = .;
		. = ALIGN(4);
		*(.data)           /* .data sections */
		*(.data*)          /* .data* sections */
		*(.sdata)          /* .sdata sections */
		*(.sdata*)         /* .sdata* sections */
		. = ALIGN(4);
		_edata = .;
	} >RAM

	/* Uninitialized data section */
	.bss :
	{
		. = ALIGN(4);
		_sbss = .;
		*(.bss)
		*(.bss*)
		*(.sbss)
		*(.sbss*)
		*(COMMON)

		. = ALIGN(4);
		_ebss = .;
	} >RAM
}

_stack_start = ORIGIN(RAM) + LENGTH(RAM);

创建入口点

以下（全局）汇编代码创建入口点 _start，在此之后设备被初始化用于加载的应用程序，之后调用函数 main。

设备从 'main' 返回时的响应似乎取决于应用程序二进制文件的优化级别。最好将 main 定义为 '#[no_mangle] extern "C" fn main() -> !'，即非返回，以避免遇到这种情况。

对原始汇编代码的修改

• 以期望符号 _stack_start 在连接器脚本中定义，用于初始化堆栈指针。

// Note: this assembly provides the initialization procedure that clears memory and finally calls
// `main` to start execution of the app-binary.
global_asm!(
    ".section \".text.init\"",
    ".global _start",
    "_start:",
    "li x1, 0",
    "li x2, 0",
    "li x3, 0",
    "li x4, 0",
    "li x5, 0",
    "li x6, 0",
    "li x7, 0",
    "li x8, 0",
    "li x9, 0",
    "li x10,0",
    "li x11,0",
    "li x12,0",
    "li x13,0",
    "li x14,0",
    "li x15,0",
    "li x16,0",
    "li x17,0",
    "li x18,0",
    "li x19,0",
    "li x20,0",
    "li x21,0",
    "li x22,0",
    "li x23,0",
    "li x24,0",
    "li x25,0",
    "li x26,0",
    "li x27,0",
    "li x28,0",
    "li x29,0",
    "li x30,0",
    "li x31,0",
    /* init stack below 0x40020000 (TK1_RAM_BASE+TK1_RAM_SIZE) */
    "la sp, _stack_start",
    /* zero-init bss section */
    "la a0, _sbss",
    "la a1, _ebss",
    "bge a0, a1, end_init_bss",
    "loop_init_bss:",
    "sw zero, 0(a0)",
    "addi a0, a0, 4",
    "blt a0, a1, loop_init_bss",
    "end_init_bss:",
    "call main",
    options(raw)
);

创建原始应用程序二进制文件

使用 'llvm-objcopy --input-target=elf32-littleriscv --output-target=binary target/riscv32i-unknown-none-elf/release/example example.bin' 生成加载到 TKey 上的原始二进制数据。

应用程序

此时，设置已经完成，直到进入函数 main 的应用程序。

有一些推荐